Всем привет, возникла необходимость программного добавления колонки в таблицу элемента формы, чтобы не снимать с поддержки затянул форму в расширение, но при выполнении кода выходит ошибка.
по причине:

&НаСервере
Процедура Расш1_ПриСозданииНаСервереПосле(Отказ, СтандартнаяОбработка)
	
	ДобавляемыеРеквизиты = Новый Массив;
	Реквизит_ДоговорКонтрагента = Новый РеквизитФормы("ДоговорКонтрагента",	Новый ОписаниеТипов("СправочникСсылка.ДоговорыКонтрагентов"), "ЭтаФорма.ДокументыКИмпорту", "Договор контрагента");
	ДобавляемыеРеквизиты.Добавить(Реквизит_ДоговорКонтрагента);
	ИзменитьРеквизиты(ДобавляемыеРеквизиты);
	
	НовыйЭлемент = Элементы.Добавить("ДокументыКИмпортуДоговорКонтрагента", Тип("ПолеФормы"), Элементы.ДокументыКИмпорту);
	НовыйЭлемент.ПутьКДанным = "ЭтаФорма.ДокументыКИмпорту.ДоговорКонтрагента";
	НовыйЭлемент.Вид = ВидПоляФормы.ПолеВвода;
		
КонецПроцедуры

как указать путь? если элемент "ДокументыКИмпорту" это реквизит формы а не объекта.
https://iimg.su/i/lhTqhm

google:
1c динамически добавить колонку в таблицу значений


https://fastcode.im/Templates/6972/tablicza-znachenij-na-uf-s-dinamicheskim-naborom-kolonok

(0) решение, нужно без обращения через точку
НоваяКолонка.ПутьКДанным = "ДокументыКИмпорту.ДоговорКонтрагента";

колонка добавилась как для нее описать обработчик в расширении? т.е. при открытии поля чтобы был отбор по контрагенту а не как сейчас все договора всех контрагентов.
https://iimg.su/i/WWcOG7

(3) Заполни СвязиПараметровВыбора для поля формы (НовыйЭлемент из (0))

(4) благодарю получилось

ДобавляемыеРеквизиты = Новый Массив;
	Реквизит_ДоговорКонтрагента = Новый РеквизитФормы("ДоговорКонтрагента",	Новый ОписаниеТипов("СправочникСсылка.ДоговорыКонтрагентов"), "ДокументыКИмпорту", "Договор контрагента");
	ДобавляемыеРеквизиты.Добавить(Реквизит_ДоговорКонтрагента);
	ИзменитьРеквизиты(ДобавляемыеРеквизиты);
	
	НоваяКолонка = Элементы.Добавить("ДоговорКонтрагента", Тип("ПолеФормы"), Элементы.ДокументыКИмпорту);

    НоваяКолонка.Заголовок = "Договор контрагента";
    НоваяКолонка.ПутьКДанным = "ДокументыКИмпорту.ДоговорКонтрагента";
    НоваяКолонка.Вид = ВидПоляФормы.ПолеВвода;
        
    НоваяКолонка.СвязиПараметровВыбора = Новый ФиксированныйМассив(Новый Массив);
    НоваяСвязь = Новый СвязьПараметраВыбора("Отбор.Владелец", "Элементы.ДокументыКИмпорту.ТекущиеДанные.Контрагент");
    НовыйМассив = Новый Массив();
    НовыйМассив.Добавить(НоваяСвязь);
    НоваяКолонка.СвязиПараметровВыбора = Новый ФиксированныйМассив(НовыйМассив);

(5)

   НоваяКолонка.СвязиПараметровВыбора = Новый ФиксированныйМассив(Новый Массив); /// Вот это лишнее, достаточно последней строки
    НоваяСвязь = Новый СвязьПараметраВыбора("Отбор.Владелец", "Элементы.ДокументыКИмпорту.ТекущиеДанные.Контрагент");

(0) Откройте уже для себя https://infostart.ru/1c/articles/1284403/