Для обмена КД3 сделан свой XDTO пакет EnterpriseData (для чего не спрашивайте).
Надо, чтобы обмен через универсальный формат использовал его, а не типовой пакет.*

Где это настраивается?

найди поиском в коде по имени рабочего пакета.

(0) "Безумству храбрых поем мы песню"...
Весь формат EnterpriseData был придуман для того чтобы не исправлять его кроме самой 1С, чтобы программисты не сломали его.

(0) модуль менеджера плана обмена СинхронизацияДанныхЧерезУниверсальныйФормат, процедура ПриПолученииНастроек.

Настройки.ФорматОбмена = "http://v8.1c.ru/edi/edi_stnd/EnterpriseData";

тут должен быть URL из вашего пакета

Как минимум нужно менять менеджер обмена, ведь он заточен под текущий пакет

Надо добавить в расширения
Свой пакет, указать такое же URL пространство как и заменяемого пакета

Модули рсширения для модификации
    ОбменДаннымиПереопределяемый    
&После("ПриПолученииДоступныхРасширенийФормата")
Процедура _ПриПолученииДоступныхРасширенийФормата(РасширенияФормата)
    

    // для 2.5.17
    РасширенияФормата.Вставить("http://v8.1c.ru/edi/edi_stnd/EnterpriseData/1.17" , "1.17");
    
КонецПроцедуры

    ОбменДаннымиСервер    (можно сделать после)

&ИзменениеИКонтроль("НастройкиПланаОбменаПоУмолчанию")
Функция _НастройкиПланаОбменаПоУмолчанию(ИмяПланаОбмена)
    
    НазначениеПланаОбмена = "СинхронизацияСДругойПрограммой";
    Если ОбменДаннымиПовтИсп.ЭтоПланОбменаРаспределеннойИнформационнойБазы(ИмяПланаОбмена) Тогда
        НазначениеПланаОбмена = "РИБ";
    КонецЕсли;
    
    Алгоритмы = Новый Структура;
    Алгоритмы.Вставить("ПриПолученииВариантовНастроекОбмена",          Ложь);
    Алгоритмы.Вставить("ПриПолученииОписанияВариантаНастройки",        Ложь);
    
    Алгоритмы.Вставить("ОписаниеОграниченийПередачиДанных",            Ложь);
    Алгоритмы.Вставить("ОписаниеЗначенийПоУмолчанию",                  Ложь);
    
    Алгоритмы.Вставить("ПредставлениеОтбораИнтерактивнойВыгрузки",     Ложь);
    Алгоритмы.Вставить("НастроитьИнтерактивнуюВыгрузку",               Ложь);
    Алгоритмы.Вставить("НастроитьИнтерактивнуюВыгрузкуВМоделиСервиса", Ложь);
    
    Алгоритмы.Вставить("ОбработчикПроверкиОграниченийПередачиДанных",  Ложь);
    Алгоритмы.Вставить("ОбработчикПроверкиЗначенийПоУмолчанию",        Ложь);
    Алгоритмы.Вставить("ОбработчикПроверкиПараметровУчета",            Ложь);
    
    Алгоритмы.Вставить("ПриПодключенииККорреспонденту",                Ложь);
    Алгоритмы.Вставить("ПриПолученииДанныхОтправителя",                Ложь);
    Алгоритмы.Вставить("ПриОтправкеДанныхОтправителя",                 Ложь);
    
    Алгоритмы.Вставить("ПриСохраненииНастроекСинхронизацииДанных",     Ложь);
    
    Алгоритмы.Вставить("ПриОпределенииПоддерживаемыхОбъектовФормата",  Ложь);
    Алгоритмы.Вставить("ПриОпределенииПоддерживаемыхКорреспондентомОбъектовФормата", Ложь);
    
    Алгоритмы.Вставить("ПередНастройкойСинхронизацииДанных",           Ложь);
    
    Параметры = Новый Структура;
    Параметры.Вставить("ВариантыНастроекОбмена",                         КоллекцияВариантовНастроекОбмена());
    Параметры.Вставить("ИмяКонфигурацииИсточника",                       "");
    Параметры.Вставить("ИмяКонфигурацииПриемника",                       Новый Структура);
    Параметры.Вставить("ВерсииФорматаОбмена",                            Новый Соответствие);
    Параметры.Вставить("ФорматОбмена",                                   "");
    Параметры.Вставить("РасширенияФорматаОбмена",                        Новый Соответствие);
    Параметры.Вставить("ПланОбменаИспользуетсяВМоделиСервиса",           Ложь);
    Параметры.Вставить("ЭтоПланОбменаXDTO",                              Ложь);
    Параметры.Вставить("ИмяПланаОбменаДляПереходаНаНовыйОбмен",          "");
    Параметры.Вставить("ПредупреждатьОНесоответствииВерсийПравилОбмена", Истина);
    Параметры.Вставить("НазначениеПланаОбмена",                          НазначениеПланаОбмена);
    Параметры.Вставить("НаличиеПравилКонвертацииОбязательно",            Истина);
    Параметры.Вставить("РежимВыборочнойРегистрации",                     Неопределено);
    Параметры.Вставить("Алгоритмы",                                      Алгоритмы);
    Параметры.Вставить("ПравилаРегистрацииВМенеджере", Ложь);
    Параметры.Вставить("ИмяМенеджераРегистрации", "");
    Параметры.Вставить("ИспользоватьКешПубличныхИдентификаторов", Ложь);
    Параметры.Вставить("Глобальный", Ложь);
#Вставка
    // для 2.5.17
    Параметры.РасширенияФорматаОбмена.Вставить("http://v8.1c.ru/edi/edi_stnd/EnterpriseData/1.17");
#КонецВставки    
    Возврат Параметры;
    
КонецФункции

А почему у вас пространство имен совпадает с основным пакетом?
У нас вот так

&ИзменениеИКонтроль("ПриПолученииДоступныхРасширенийФормата")
Процедура кмн_ПриПолученииДоступныхРасширенийФормата(РасширенияФормата)


	#Вставка
	РасширенияФормата.Вставить("http://v8.1c.ru/edi/edi_stnd/EnterpriseDataExt", "1.11");
	#КонецВставки
КонецПроцедуры

ну и настройки

&ИзменениеИКонтроль("ПриПолученииНастроек")
Процедура кмн_ПриПолученииНастроек(Настройки)

	Настройки.ИмяКонфигурацииИсточника = Метаданные.Имя;

	Настройки.ЭтоПланОбменаXDTO = Истина;
	Настройки.ПредупреждатьОНесоответствииВерсийПравилОбмена = Ложь;
	Настройки.ФорматОбмена = "http://v8.1c.ru/edi/edi_stnd/EnterpriseData";

	ВерсииФормата = Новый Соответствие;
	ПолучитьВерсииФорматаОбмена(ВерсииФормата);

	Настройки.ВерсииФорматаОбмена = ВерсииФормата;

	Настройки.ПланОбменаИспользуетсяВМоделиСервиса = Истина;

	Настройки.Алгоритмы.ПриПолученииВариантовНастроекОбмена   = Истина;
	Настройки.Алгоритмы.ПриПолученииОписанияВариантаНастройки = Истина;

	Настройки.Алгоритмы.ПредставлениеОтбораИнтерактивнойВыгрузки = Истина;
	Настройки.Алгоритмы.НастроитьИнтерактивнуюВыгрузку           = Истина;

	#Вставка
	Настройки.РасширенияФорматаОбмена.Вставить("http://v8.1c.ru/edi/edi_stnd/EnterpriseDataExt", "1.11");
	#КонецВставки
	
КонецПроцедуры

Ну и в самом модуле менеджера обмена уже так

&ИзменениеИКонтроль("ДобавитьПКО_Справочник_Контрагенты_Отправка")
Процедура кмн_ДобавитьПКО_Справочник_Контрагенты_Отправка(ПравилаКонвертации)
	
	ПравилоКонвертации = ОбменДаннымиXDTOСервер.ИнициализироватьПравилоКонвертацииОбъекта(ПравилаКонвертации);
	ПравилоКонвертации.ИмяПКО            = "Справочник_Контрагенты_Отправка";
	ПравилоКонвертации.ОбъектДанных      = Метаданные.Справочники.Контрагенты;
	ПравилоКонвертации.ОбъектФормата     = "Справочник.Контрагенты";
	ПравилоКонвертации.ПриОтправкеДанных = "ПКО_Справочник_Контрагенты_Отправка_ПриОтправкеДанных";
	
	СвойстваШапки = ПравилоКонвертации.Свойства;
	ДобавитьПКС(СвойстваШапки, "ГоловнойКонтрагент",     "ГоловнойКонтрагент", , "Справочник_Контрагенты_Отправка");
	ДобавитьПКС(СвойстваШапки, "ИНН",                    "ИНН");
	ДобавитьПКС(СвойстваШапки, "КодПоОКПО",              "ОКПО");
	ДобавитьПКС(СвойстваШапки, "Комментарий",            "ДополнительнаяИнформация");
	ДобавитьПКС(СвойстваШапки, "КПП",                    "КПП");
	ДобавитьПКС(СвойстваШапки, "Наименование",           "Наименование");
	ДобавитьПКС(СвойстваШапки, "НаименованиеПолное",     "НаименованиеПолное");
	ДобавитьПКС(СвойстваШапки, "НалоговыйНомер",         "НалоговыйНомерНерезидента");
	ДобавитьПКС(СвойстваШапки, "ОГРН",                   "РегистрационныйНомерНерезидента");
	ДобавитьПКС(СвойстваШапки, "ОсновнойБанковскийСчет", "ОсновнойБанковскийСчет", , "Справочник_БанковскиеСчета_Отправка");
	#Удаление
	ДобавитьПКС(СвойстваШапки, "Родитель",               "Группа", , "Справочник_КонтрагентыГруппа");
	#КонецУдаления
	ДобавитьПКС(СвойстваШапки, "СтранаРегистрации",      "СтранаРегистрации", , "Справочник_СтраныМира");
	ДобавитьПКС(СвойстваШапки, "ФормаСобственности",     "ЮридическоеФизическоеЛицо", , "Перечисление_ФизическоеЮридическоеЛицо");
	ДобавитьПКС(СвойстваШапки, "",                       "ИндивидуальныйПредприниматель", 1);
	ДобавитьПКС(СвойстваШапки, "",                       "ОбособленноеПодразделение", 1);
	
	СвойстваТЧ = ДобавитьПКТЧ(ПравилоКонвертации, "", "КонтактнаяИнформация");
	ДобавитьПКС(СвойстваТЧ, "", "ВидКонтактнойИнформации", 1);
	ДобавитьПКС(СвойстваТЧ, "", "ЗначенияПолей", 1);
	ДобавитьПКС(СвойстваТЧ, "", "НаименованиеКонтактнойИнформации", 1);
	
	#Вставка
	// ++ 2023 06 22 #7772
	ДобавитьПКС(СвойстваШапки, "",           "кмн_ЮрФизЛицо", 1);
	ДобавитьПКС(СвойстваШапки, "",           "кмн_ЭтоИП", 1);
	ОбменДаннымиXDTOСервер.ИнициализироватьРасширениеПравилаКонвертацииОбъекта(ПравилоКонвертации, "http://v8.1c.ru/edi/edi_stnd/EnterpriseDataExt");
	// -- 2023 06 22 #7772
	#КонецВставки
	
КонецПроцедуры

(0) а какая у вас цель была, если не секрет, чтобы новый пакет создавать?