УТ 11.
Есть табличная часть, учет по характеристикам может вестись, а может и нет. Получаю запросом остатки номенклатуры на дату. В параметр запроса передаю массив номенклатуры, выгруженный из ТЧ. Как можно передать в запрос характеристики, чтобы найти остатки и по ним сразу?

Запрос = Новый Запрос;
   Запрос.Текст =
   "ВЫБРАТЬ
   |    СвободныеОстаткиОстатки.Номенклатура,
   |    СвободныеОстаткиОстатки.Характеристика,
   |    ВЫБОР
   |        КОГДА СвободныеОстаткиОстатки.ВНаличииОстаток - СвободныеОстаткиОстатки.ВРезервеОстаток > 0
   |            ТОГДА СвободныеОстаткиОстатки.ВНаличииОстаток - СвободныеОстаткиОстатки.ВРезервеОстаток
   |        ИНАЧЕ 0
   |    КОНЕЦ КАК Поле1
   |ИЗ
   |    РегистрНакопления.СвободныеОстатки.Остатки(
   |            &Дата,
   |            Номенклатура В (&МассивНоменклатуры)
   |                И Склад = &Склад) КАК СвободныеОстаткиОстатки";
   Запрос.УстановитьПараметр("Дата", ОбъектыПечати.Дата);
   Запрос.УстановитьПараметр("Склад", ОбъектыПечати.Склад);
   МассивНоменклатуры = ОбъектыПечати.Товары.ВыгрузитьКолонку("Номенклатура");    
   Запрос.УстановитьПараметр("МассивНоменклатуры", МассивНоменклатуры);

Документ "Заказ клиента". Колонка характеристики там по умолчанию

может кто получал остатки по номенклатуре при использовании характеристик?

ВЫБРАТЬ
   |    Товары.Номенклатура,
   |    Товары.Характеристика,
   |    Товары.Количество КАК Заказано,
   |    СвободныеОстаткиОстатки.ВНаличииОстаток
   |ИЗ
   |    РегистрНакопления.СвободныеОстатки.Остатки(
   |            &Дата,
   |            Склад = &Склад) КАК СвободныеОстаткиОстатки
|ПРАВОЕ СОЕДИНЕНИЕ Документ.ЗаказКлиента.Товары КАК Товары
|ПО Товары.Номенклатура = СвободныеОстаткиОстатки.Номенклатура И
|Товары.Характеристика = СвободныеОстаткиОстатки.Характеристика
|ГДЕ Товары.Ссылка = &СсылкаНаТвойДокумент";

(4) спасибо)
туплю уже под вечер

(4) Плохо же!

"ВЫБРАТЬ
   |    СвободныеОстаткиОстатки.Номенклатура,
   |    СвободныеОстаткиОстатки.Характеристика,
   |    ВЫБОР
   |        КОГДА СвободныеОстаткиОстатки.ВНаличииОстаток - СвободныеОстаткиОстатки.ВРезервеОстаток > 0
   |            ТОГДА СвободныеОстаткиОстатки.ВНаличииОстаток - СвободныеОстаткиОстатки.ВРезервеОстаток
   |        ИНАЧЕ 0
   |    КОНЕЦ КАК Остаток
   |ИЗ
   |    РегистрНакопления.СвободныеОстатки.Остатки(
   |            &Дата,
   |            Номенклатура В (&МассивНоменклатуры)
   |                И Склад = &Склад
   |                И Характеристика В (&МассивХарактеристик)) КАК СвободныеОстаткиОстатки";

(6) ну, лучше, чем изначально все же

В (7) - оптимальный, а вот - кошерный

   "ВЫБРАТЬ
   |    СвободныеОстаткиОстатки.Номенклатура,
   |    СвободныеОстаткиОстатки.Характеристика,
   |    ВЫБОР
   |        КОГДА СвободныеОстаткиОстатки.ВНаличииОстаток - СвободныеОстаткиОстатки.ВРезервеОстаток > 0
   |            ТОГДА СвободныеОстаткиОстатки.ВНаличииОстаток - СвободныеОстаткиОстатки.ВРезервеОстаток
   |        ИНАЧЕ 0
   |    КОНЕЦ КАК Остаток
   |ИЗ
   |    РегистрНакопления.СвободныеОстатки.Остатки(
   |            &Дата,
   |            Склад = &Склад
   |                И (Номенклатура, Характеристика) В
   |                    (ВЫБРАТЬ
   |                        ЗаказКлиентаТовары.Номенклатура,
   |                        ЗаказКлиентаТовары.Характеристика
   |                    ИЗ
   |                        Документ.ЗаказКлиента.Товары КАК ЗаказКлиентаТовары
   |                    ГДЕ
   |                        ЗаказКлиентаТовары.Ссылка = &Ссылка)) КАК СвободныеОстаткиОстатки";

(9)
тогда еще кошернее во временную таблицу сей подзапрос:
   |                    (ВЫБРАТЬ
   |                        ЗаказКлиентаТовары.Номенклатура,
   |                        ЗаказКлиентаТовары.Характеристика
   |                    ИЗ
   |                        Документ.ЗаказКлиента.Товары КАК ЗаказКлиентаТовары
   |                    ГДЕ
   |                        ЗаказКлиентаТовары.Ссылка = &Ссылка)

:)

(7) так я и сам делал. Смущает что 2 несвязанных массива передаются. Понятно, что из одной ТЧ выгружены, но все-таки

к (11)
В табличной части есть колонка "Дата отгрузки", остатки надо получать на эти даты.
Если в (4) передам массив дат вместо даты, запрос будет корректно работать?

(12) Нет

да и массив туда не передается))

ВЫБРАТЬ
   ЗаказКлиентаТовары.Количество,
   ЗаказКлиентаТовары.Номенклатура,
   ЗаказКлиентаТовары.Характеристика,
   СвободныеОстаткиОстаткиИОбороты.ВНаличииКонечныйОстаток,
   СвободныеОстаткиОстаткиИОбороты.ВРезервеКонечныйОстаток,
   СвободныеОстаткиОстаткиИОбороты.ВНаличииНачальныйОстаток,
   СвободныеОстаткиОстаткиИОбороты.ВРезервеНачальныйОстаток,
   СвободныеОстаткиОстаткиИОбороты.ВНаличииОборот,
   СвободныеОстаткиОстаткиИОбороты.ВНаличииПриход,
   СвободныеОстаткиОстаткиИОбороты.ВНаличииРасход,
   СвободныеОстаткиОстаткиИОбороты.ВРезервеОборот,
   СвободныеОстаткиОстаткиИОбороты.ВРезервеПриход,
   СвободныеОстаткиОстаткиИОбороты.ВРезервеРасход,
   СвободныеОстаткиОстаткиИОбороты.Период,
   ЗаказКлиентаТовары.ДатаОтгрузки
ИЗ
   Документ.ЗаказКлиента.Товары КАК ЗаказКлиентаТовары
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.СвободныеОстатки.ОстаткиИОбороты(, , Секунда, ДвиженияИГраницыПериода, ) КАК СвободныеОстаткиОстаткиИОбороты
       ПО ЗаказКлиентаТовары.Номенклатура = СвободныеОстаткиОстаткиИОбороты.Номенклатура
           И ЗаказКлиентаТовары.Характеристика = СвободныеОстаткиОстаткиИОбороты.Характеристика
           И ЗаказКлиентаТовары.Ссылка.Склад = СвободныеОстаткиОстаткиИОбороты.Склад
           И ЗаказКлиентаТовары.ДатаОтгрузки = СвободныеОстаткиОстаткиИОбороты.Период
ГДЕ
   ЗаказКлиентаТовары.Ссылка = &Заказ

Возвращает NULL по всем ресурсам

(15) естественно, нахрена это вот прилепил

И ЗаказКлиентаТовары.ДатаОтгрузки = СвободныеОстаткиОстаткиИОбороты.Период

+(16) хоте, не, вру. Вроде всё верно.

Дата отгрузки в результате запроса заполнена

Разобрался. В строках ТЧ дата без времени. Поставил период день - все показало