Процедура глНачальноеЗаполнениеСлоевИУзлов() Экспорт
	
	НаборЗаписей = РегистрыСведений.Расчет.СоздатьНаборЗаписей();
	НаборЗаписей.Записать(ИСТИНА);
	
	Выборка = Справочники.Узлы.Выбрать();
	Пока Выборка.Следующий() Цикл
	
		текСпрО = Выборка.ПолучитьОбъект();
		текСпрО.ПометкаУдаления = Истина;
		текСпрО.Записать();
	
	КонецЦикла;
	
	Помеченные = НайтиПомеченныеНаУдаление();
	Найденные = Неопределено;
	УдалитьОбъекты(Помеченные, Ложь, Найденные);
	Для каждого Ссылка из Найденные Цикл
		СтрСообщения = "Объект не удален: " + СокрЛП(Ссылка[0]);
		СтрСсылка = ", используется в " + СокрЛП(Ссылка[1]);
		Сообщить (СтрСообщения + СтрСсылка);
	КонецЦикла;
	
	ВсегоСлоев = Константы.Слоев.Получить();
	УзловВСлое = Константы.УзловВСлое.Получить();
	
	// Входящие узлы 0-слоя
	
	НоваяГруппа = Справочники.Узлы.СоздатьГруппу();
	НоваяГруппа.Наименование = "Слой 000";
	НоваяГруппа.Записать();
	
	Группа = НоваяГруппа.Ссылка;
	
	СпсУзловПредыдущегоСлоя = Новый СписокЗначений;
	
	Для счУзлов = 1 По УзловВСлое Цикл
		
		НовыйУзел = Справочники.Узлы.СоздатьЭлемент();
		НовыйУзел.Родитель = Группа;
		НовыйУзел.Наименование = "Узел 000." + Прав("000" + Строка(счУзлов), 3);
		НовыйУзел.Слой = 0;
		НовыйУзел.НомерВСлое = счУзлов;
		НовыйУзел.Записать();
		
		СпсУзловПредыдущегоСлоя.Добавить(НовыйУзел.Ссылка);
		
	КонецЦикла;
	
	// Узлы по слоям расчета
	
	СпсУзловНовогоСлоя = Новый СписокЗначений;
	
	Для счСлоев = 1 По ВсегоСлоев Цикл
		
		НоваяГруппа = Справочники.Узлы.СоздатьГруппу();
		НоваяГруппа.Наименование = "Слой " + Прав("000" + Строка(счСлоев), 3);
		НоваяГруппа.Записать();
		
		Группа = НоваяГруппа.Ссылка;
		
		СпсУзловНовогоСлоя.Очистить();
		
		Для счУзлов = 1 По УзловВСлое Цикл
		
			НовыйУзел = Справочники.Узлы.СоздатьЭлемент();
			НовыйУзел.Родитель = Группа;
			НовыйУзел.Наименование = "Узел " + Прав("000" + Строка(счСлоев), 3) + "." + Прав("000" + Строка(счУзлов), 3);
			НовыйУзел.Слой = счСлоев;
			НовыйУзел.НомерВСлое = счУзлов;
			
			Для каждого ЭлСпс Из СпсУзловПредыдущегоСлоя Цикл
			
				стрВес = НовыйУзел.Веса.Добавить();
				стрВес.Узел = ЭлСпс.Значение;
				стрВес.Вес = 1;
			
			КонецЦикла;
			
			НовыйУзел.Записать();
		
			СпсУзловНовогоСлоя.Добавить(НовыйУзел.Ссылка);
		
		КонецЦикла;
		
		СпсУзловПредыдущегоСлоя.Очистить();
		
		Для каждого ЭлСпс Из СпсУзловНовогоСлоя Цикл
		
			СпсУзловПредыдущегоСлоя.Добавить(ЭлСпс.Значение);
		
		КонецЦикла;
	
	КонецЦикла;
	
	// Узел результата
	
	НовыйУзел = Справочники.Узлы.СоздатьЭлемент();
	НовыйУзел.Родитель = Группа;
	НовыйУзел.Наименование = "Узел результата";
	НовыйУзел.Слой = ВсегоСлоев + 1;
	НовыйУзел.НомерВСлое = 1;
			
	Для каждого ЭлСпс Из СпсУзловПредыдущегоСлоя Цикл
			
		стрВес = НовыйУзел.Веса.Добавить();
		стрВес.Узел = ЭлСпс.Значение;
		стрВес.Вес = 1;
			
	КонецЦикла;
			
	НовыйУзел.Записать();

КонецПроцедуры

Функция локПреобразоватьИзЧислаВДвоичноеЧисло(Знач Значение)
	
	Результат="";
	
	Пока Значение > 0 цикл
		Остаток = Значение % 2;
		Результат1 = Сред("01", Остаток+1, 1);
		Значение = (Значение - Остаток) / 2;
		Результат = Результат1 + Результат;
	КонецЦикла;
	
	Возврат Результат;
КонецФункции

Функция локОбработатьВход(ВходящееЧисло = 0)

	СписокЗначенийВходящий = Новый СписокЗначений;
	
	ЧислоДвоичноеСтрокой = локПреобразоватьИзЧислаВДвоичноеЧисло(ВходящееЧисло);
	
	УзловВСлое = Константы.УзловВСлое.Получить();
	
	ПервыеНули = "0";
	Для ЧЦ = 1 По УзловВСлое Цикл
	
		ПервыеНули = ПервыеНули + "0";
	
	КонецЦикла;
	
	ЧислоДвоичноеСтрокой = Прав(ПервыеНули + ЧислоДвоичноеСтрокой, УзловВСлое);
	
	ДлинаДвоичногоЧисла = СтрДлина(ЧислоДвоичноеСтрокой);
	
	Для ЧЦ = 1 По УзловВСлое Цикл
	
		СписокЗначенийВходящий.Добавить(Сред(ЧислоДвоичноеСтрокой, ЧЦ, 1));
	
	КонецЦикла;
	
	Возврат СписокЗначенийВходящий;

КонецФункции

Функция локНайтиУзелПоСлоюИНомеру(Слой, Номер)

	Ответ = Справочники.Узлы.ПустаяСсылка();
	
	Запрос = Новый Запрос;
	Запрос.Текст = 
	"ВЫБРАТЬ
	|	Узлы.Ссылка КАК Ссылка
	|ИЗ
	|	Справочник.Узлы КАК Узлы
	|ГДЕ
	|	Узлы.Слой = &Слой
	|	И Узлы.НомерВСлое = &Номер
	|	И Узлы.ПометкаУдаления = ЛОЖЬ
	|	И Узлы.ЭтоГруппа = ЛОЖЬ";
	
	Запрос.УстановитьПараметр("Слой", Слой);
	Запрос.УстановитьПараметр("Номер", Номер);
	
	Выборка = Запрос.Выполнить().Выбрать();
	
	Если Выборка.Следующий() Тогда
	
		Ответ = Выборка.Ссылка;
	
	КонецЕсли;
	
	Возврат Ответ;

КонецФункции

Функция глРасчетУзла(Узел) Экспорт
	
	Ответ = Ложь;
	
	Запрос = Новый Запрос;
	Запрос.Текст = 
	"ВЫБРАТЬ
	|	УзлыВеса.Узел КАК Узел,
	|	УзлыВеса.Вес * ЕСТЬNULL(Расчет.Значение, 0) КАК Значение
	|ПОМЕСТИТЬ ТЗУзлы
	|ИЗ
	|	Справочник.Узлы.Веса КАК УзлыВеса
	|		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.Расчет КАК Расчет
	|		ПО УзлыВеса.Узел = Расчет.Узел
	|ГДЕ
	|	УзлыВеса.Ссылка = &Узел
	|;
	|
	|////////////////////////////////////////////////////////////////////////////////
	|ВЫБРАТЬ
	|	КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ТЗУзлы.Узел) КАК КоличествоВходов
	|ПОМЕСТИТЬ ТЗКоличествоВходов
	|ИЗ
	|	ТЗУзлы КАК ТЗУзлы
	|;
	|
	|////////////////////////////////////////////////////////////////////////////////
	|ВЫБРАТЬ
	|	СУММА(ТЗУзлы.Значение) КАК СуммаВходов
	|ПОМЕСТИТЬ ТЗСуммаВходов
	|ИЗ
	|	ТЗУзлы КАК ТЗУзлы
	|;
	|
	|////////////////////////////////////////////////////////////////////////////////
	|ВЫБРАТЬ
	|	ВЫБОР КОГДА ТЗСуммаВходов.СуммаВходов >= ТЗКоличествоВходов.КоличествоВходов ТОГДА 1 ИНАЧЕ 0 КОНЕЦ КАК Результат
	|ИЗ
	|	ТЗКоличествоВходов КАК ТЗКоличествоВходов,
	|	ТЗСуммаВходов КАК ТЗСуммаВходов";
	
	Запрос.УстановитьПараметр("Узел", Узел);
	
	Выборка = Запрос.Выполнить().Выбрать();
	
	Если Выборка.Следующий() Тогда
	
		Ответ = Выборка.Результат;
	
	КонецЕсли;
	
	Возврат Ответ;

КонецФункции // глРасчетУзла()

Функция глПроизвестиРасчет(ВходящееЧисло = 0) Экспорт
	
	Ответ = 0;
	
	СписокВходящий = локОбработатьВход(ВходящееЧисло);	
	
	ВсегоСлоев = Константы.Слоев.Получить();
	УзловВСлое = Константы.УзловВСлое.Получить();
	
	// Заполняем входящий нулевой слой
	
	Для счУзлов = 1 По УзловВСлое Цикл
	
		текУзел = локНайтиУзелПоСлоюИНомеру(0, счУзлов);
		
		текЗначение = ?(СписокВходящий.Получить(счУзлов - 1) = "1", 1, 0);
		
		НаборЗаписей = РегистрыСведений.Расчет.СоздатьНаборЗаписей();
		НаборЗаписей.Отбор.Узел.Установить(текУзел);
		
		НоваяЗапись = НаборЗаписей.Добавить();
		НоваяЗапись.Активность = Истина;
		НоваяЗапись.Узел = текУзел;
		НоваяЗапись.Значение = текЗначение;
		
		НаборЗаписей.Записать(Истина);
	
	КонецЦикла;
	
	// Включаем думатель
	
	Для счСлоев = 1 По ВсегоСлоев Цикл
		
		Для счУзлов = 1 По УзловВСлое Цикл
		
			текУзел = локНайтиУзелПоСлоюИНомеру(счСлоев, счУзлов);
			
			текЗначение = глРасчетУзла(текУзел);
		
			НаборЗаписей = РегистрыСведений.Расчет.СоздатьНаборЗаписей();
			НаборЗаписей.Отбор.Узел.Установить(текУзел);
			
			НоваяЗапись = НаборЗаписей.Добавить();
			НоваяЗапись.Активность = Истина;
			НоваяЗапись.Узел = текУзел;
			НоваяЗапись.Значение = текЗначение;
			
			НаборЗаписей.Записать(Истина);
		
		КонецЦикла;
	
	КонецЦикла;
	
	// Запускаем анализатор
	
	текУзел = локНайтиУзелПоСлоюИНомеру(ВсегоСлоев + 1, 1);
			
	текЗначение = глРасчетУзла(текУзел);
	
	Ответ = текЗначение;
	
	Возврат Ответ;
	
КонецФункции


Процедура глОбучение(Ответ, ПравильныйОтвет) Экспорт
	
	ВсегоСлоев = Константы.Слоев.Получить();
	СуммаСлоев = ВсегоСлоев * (ВсегоСлоев + 1) / 2;
	
	// Выбираем исправляемые узлы
	
	Запрос = Новый Запрос;
	Запрос.Текст = 
	"ВЫБРАТЬ
	|	Расчет.Узел КАК Узел
	|ИЗ
	|	РегистрСведений.Расчет КАК Расчет
	|ГДЕ
	|	Расчет.Значение = &Ответ";
	
	Запрос.УстановитьПараметр("Ответ", Ответ);
	
	Выборка = Запрос.Выполнить().Выбрать();
	
	Запрос = Новый Запрос;
	Запрос.Текст = 
	"ВЫБРАТЬ
	|	Расчет.Значение КАК Значение
	|ИЗ
	|	РегистрСведений.Расчет КАК Расчет
	|ГДЕ
	|	Расчет.Узел = &Узел";
	
	Пока Выборка.Следующий() Цикл
		
		текУзел = Выборка.Узел.ПолучитьОбъект();
		
		Если текУзел.Слой = 0 ИЛИ текУзел.Слой > ВсегоСлоев Тогда
		
			Продолжить;
		
		КонецЕсли;
	
		Для каждого стрВеса Из текУзел.Веса Цикл
		
			текУзелВход = стрВеса.Узел;
			текРезультат = 0;
			
			Запрос.УстановитьПараметр("Узел", текУзелВход);
			
			ВыборкаРезультат = Запрос.Выполнить().Выбрать();
			
			Если Выборка.Следующий() Тогда
			
				текРезультат = Выборка.Значение;	
			
			КонецЕсли;
			
			Если текРезультат = Ответ Тогда
				
				текДельта = ?(Ответ = ПравильныйОтвет, 1, -1) * текУзел.Слой / СуммаСлоев;
				
				стрВеса.Вес = стрВеса.Вес + текДельта;
			
			КонецЕсли;
		
		КонецЦикла;
		
		текУзел.Записать();
		
	КонецЦикла;
	

КонецПроцедуры