Добрый день. Есть некий код:

&НаКлиенте
Процедура ТоварыНоменклатураПриИзменении(Элемент)
    Если НЕ ЗначениеЗаполнено(Объект.Основание) Тогда
        Предупреждение("Сначала заполните Основание");
        Возврат;
    КонецЕсли;
    Тек = Элементы.Товары.ТекущиеДанные;
    ТоварыНоменклатураПриИзмененииНаСервере(Тек.Номенклатура, Элементы.Товары.ТекущаяСтрока, Тек.Количество);
КонецПроцедуры

&НаСервере
Процедура ТоварыНоменклатураПриИзмененииНаСервере(Номен, ТекСтрока, Количество)
    Запрос = Новый Запрос;
    Запрос.Текст =
    "ВЫБРАТЬ
    |    ПоступлениеТоваровУслугТовары.Номенклатура,
    |    СУММА(ПоступлениеТоваровУслугТовары.Количество) КАК Количество
    |ИЗ
    |    Документ.ПоступлениеТоваровУслуг.Товары КАК ПоступлениеТоваровУслугТовары
    |ГДЕ
    |    ПоступлениеТоваровУслугТовары.Номенклатура = &Номенклатура
    |    И ПоступлениеТоваровУслугТовары.Ссылка = &Ссылка
    |
    |СГРУППИРОВАТЬ ПО
    |    ПоступлениеТоваровУслугТовары.Номенклатура";
    Запрос.УстановитьПараметр("Ссылка", Объект.Основание);
    Запрос.УстановитьПараметр("Номенклатура", Номен);
    Результат = Запрос.Выполнить().Выгрузить();
    Если Результат.Количество() = 0 Тогда
        Сообщить("Номенклатуры " + Номен + " нет в документе, указанном в Основании.");
        Объект.Товары.Удалить(ТекСтрока);
        Возврат;
    ИначеЕсли Количество <> 0 И Результат[0].Количество < Количество Тогда
        Сообщить("Вы пытаетесь списать больше, чем есть. Не хватает " + (Количество - Результат[0].Количество) + " шт.");
        Объект.Товары[ТекСтрока].Количество = Результат[0].Количество;
    КонецЕсли;
КонецПроцедуры

Когда смотрю по отладке в этой строке
Объект.Товары[ТекСтрока].Количество = Результат[0].Количество;
количество изменяется. Вроде все нормально, но как только возвращаемся с сервера на клиент, все сбрасывается до того, как было до изменения.
Но. Если мы в объявлении процедуры вместо этого
Процедура ТоварыНоменклатураПриИзмененииНаСервере(Номен, ТекСтрока, Количество)
пишем это
Процедура ТоварыНоменклатураПриИзмененииНаСервере(знач Номен, знач ТекСтрока, знач Количество)
то все ок.
Я погуглила, но ничего не нашла по этой теме. Может мне кто-нибудь это объяснить?

https://its.1c.ru/db/metod8dev#content:2606:hdoc

Странно. На первый взгляд никаких сайд-эффектов не нахожу.
Да и количество/текстрока - это числа, они и так передаются по значению.

Тьфу, опять забыл что в 1С все по ссылке передается.

(3) В Go все по умолчание по значению, сначала было непривычно целых два часа себя одергивал постоянно, потом привык.

Не знаю, почему поведение отличается, но вот эта строка неправильная:
Объект.Товары[ТекСтрока].Количество = Результат[0].Количество;
Правильная:
Объект.Товары.НайтиПоИдентификатору(ТекСтрока).Количество = Результат[0].Количество;

(5) а в Текстрока не идентификато будет

(6) хотя я могу врать

(7) Ага :)

(8) да, ТекСтрока - это другое. Это идентификатор.

(8) Это важно, если вы удаляете в процессе строчки. Или меняете местами. Тогда идентификатор сбивается и уже не равен номеру строки.

(9) я мало того что болтун, так еще и жадный до букв

Думаю, просто совпало когда при одном тесте идентификатор совпал с индексом и получилось что ожидалось, а в другом тесте они отличались и количество поменялось в другой строке. И удаление строки там тоже неправильное.

А не, вру. Удаление как раз правильное.

Тьфу, да что ж такое :) Таки неправильное. Удаление либо по индексу, либо по элементу строки работает.

Во-первых, чета фотки нет))
Во-вторых, а как проверялось, что "количество изменяется. Вроде все нормально, но как только возвращаемся с сервера на клиент, все сбрасывается до того, как было до изменения."
Ну в-третьих, имхо, дело вот в чем
Процедура ТоварыНоменклатураПриИзмененииНаСервере(Номен, ТекСтрока, ЗНАЧ Количество)
После возврата с сервера, устанавливается старое количество.
Соответственно, если без ЗНАЧ писать не
        Объект.Товары[ТекСтрока].Количество = Результат[0].Количество;
а просто
Количество = Результат[0].Количество
То все будет гут)

(15) > После возврата с сервера, устанавливается старое количество.
Это что еще за новости?

(16) Ну я просто предположил. Потому и во-вторых еще было)
Оно ж не по значению передавалось, на сервере элемент не менялся, вот и осталось в нем старое значение. Сам не проверял, просто предположил.

И было бы еще интересно посмотреть на ТЧ при повторном заходе на сервер до изменений.

все очень просто,значения если не написано знач должны передаваться по ссылке,но 1с не может передать ссылку с клиента на сервер,она передает туда значение,а при выходе из процедуры передает обратно

(19) О как...значит, я оказался прав, ошибившись только в нюансах.

(20) ошибившись -> ошибся

Проверил на обычном реквизите. Передал в серверную процедуру элемента формы "ТекстРедактирования" (тестНаСервере(Элементы.Мойрек.ТекстРедактирования);). Если не указать "Знач", то при возврате из серверной процедуры:
Поле объекта недоступно для записи (ТекстРедактирования)
    тестНаСервере(Элементы.Мойрек.ТекстРедактирования);

(0) кстати - хорошая задачка на тестирование

+(19) поэтому просто не думая - надо выработать привычку везде, где не нужно изменение значения параметра функции - писать Знач

(19) Вот блин. Таки да. Жесть жестяная.