УТ 11.1 и весы с печатью этикеток

Процедура СформироватьПечатныеФормы(ИмяМенеджераПечати, Знач ИменаМакетов, МассивОбъектов, ПараметрыПечати,
    КоллекцияПечатныхФорм, ОбъектыПечати = Неопределено, ПараметрыВывода) Экспорт

    ПараметрыВывода = ПодготовитьСтруктуруПараметровВывода();

    Если ОбъектыПечати = Неопределено Тогда
        ОбъектыПечати = Новый СписокЗначений;
    КонецЕсли;

    КоллекцияПечатныхФорм = ПодготовитьКоллекциюПечатныхФорм(Новый Массив);

    Если ТипЗнч(ИменаМакетов) = Тип("Строка") Тогда
        ИменаМакетов = СтроковыеФункцииКлиентСервер.РазложитьСтрокуВМассивПодстрок(ИменаМакетов);
    Иначе // Тип("Массив")
        ИменаМакетов = ОбщегоНазначенияКлиентСервер.СкопироватьМассив(ИменаМакетов);
    КонецЕсли;

    ПрефиксВнешнихПечатныхФорм  = "ВнешняяПечатнаяФорма.";
    ИсточникВнешнихПечатныхФорм = ИмяМенеджераПечати;
    Если МассивОбъектов.Количество() > 0 Тогда
        ИсточникВнешнихПечатныхФорм = МассивОбъектов[0].Метаданные().ПолноеИмя();
    КонецЕсли;
    ВнешниеПечатныеФормы = СписокПечатныхФормИзВнешнихИсточников(ИсточникВнешнихПечатныхФорм);

    // добавление внешних печатных форм в комплект
    ДобавленныеВнешниеПечатныеФормы = Новый Массив;
    Если ТипЗнч(ПараметрыПечати) = Тип("Структура")
        И ПараметрыПечати.Свойство("ДополнитьКомплектВнешнимиПечатнымиФормами")
        И ПараметрыПечати.ДополнитьКомплектВнешнимиПечатнымиФормами Тогда

        ИдентификаторыВнешнихПечатныхФорм = ВнешниеПечатныеФормы.ВыгрузитьЗначения();
        Для Каждого Идентификатор Из ИдентификаторыВнешнихПечатныхФорм Цикл
            Если ИменаМакетов.Найти(ПрефиксВнешнихПечатныхФорм + Идентификатор) = Неопределено Тогда
                ИменаМакетов.Добавить(ПрефиксВнешнихПечатныхФорм + Идентификатор);
                ДобавленныеВнешниеПечатныеФормы.Добавить(ПрефиксВнешнихПечатныхФорм + Идентификатор);
            КонецЕсли;
        КонецЦикла;
    КонецЕсли;

    Для Каждого ИмяМакета Из ИменаМакетов Цикл
        // проверка наличия уже напечатанной формы
        НайденнаяПечатнаяФорма = КоллекцияПечатныхФорм.Найти(ИмяМакета, "ИмяМакета");
        Если НайденнаяПечатнаяФорма <> Неопределено Тогда
            ПоследняяДобавленнаяПечатнаяФорма = КоллекцияПечатныхФорм[КоллекцияПечатныхФорм.Количество()-1];
            Если ПоследняяДобавленнаяПечатнаяФорма.ИмяМакета = НайденнаяПечатнаяФорма.ИмяМакета Тогда
                ПоследняяДобавленнаяПечатнаяФорма.Экземпляров = ПоследняяДобавленнаяПечатнаяФорма.Экземпляров + 1;
            Иначе
                КопияПечатнойФормы = КоллекцияПечатныхФорм.Добавить();
                ЗаполнитьЗначенияСвойств(КопияПечатнойФормы, НайденнаяПечатнаяФорма);
                КопияПечатнойФормы.Экземпляров = 1;
            КонецЕсли;
            Продолжить;
        КонецЕсли;

        // поиск указания дополнительного менеджера печати в имени печатной формы
        ИмяДополнительногоМенеджераПечати = "";
        Идентификатор = ИмяМакета;
        ВнешняяПечатнаяФорма = Неопределено;
        Если Найти(Идентификатор, ПрефиксВнешнихПечатныхФорм) > 0 Тогда // это внешняя печатная форма
            Идентификатор = Сред(Идентификатор, СтрДлина(ПрефиксВнешнихПечатныхФорм) + 1);
            ВнешняяПечатнаяФорма = ВнешниеПечатныеФормы.НайтиПоЗначению(Идентификатор);
        ИначеЕсли Найти(Идентификатор, ".") > 0 Тогда // указан дополнительный менеджер печати
            Позиция = СтроковыеФункцииКлиентСервер.НайтиСимволСКонца(Идентификатор, ".");
            ИмяДополнительногоМенеджераПечати = Лев(Идентификатор, Позиция - 1);
            Идентификатор = Сред(Идентификатор, Позиция + 1);
        КонецЕсли;

        ВременнаяКоллекцияДляОднойПечатнойФормы = ПодготовитьКоллекциюПечатныхФорм(Идентификатор);

        Если ВнешняяПечатнаяФорма <> Неопределено Тогда
            // печать внешней печатной формы
            УправлениеПечатьюПереопределяемый.ПечатьПоВнешнемуИсточнику(
                ВнешняяПечатнаяФорма(ВнешняяПечатнаяФорма.Значение, ИсточникВнешнихПечатныхФорм),
                Новый Структура("ИдентификаторКоманды, ОбъектыНазначения", ВнешняяПечатнаяФорма.Значение, МассивОбъектов),
                ВременнаяКоллекцияДляОднойПечатнойФормы,
                ОбъектыПечати,
                ПараметрыВывода);
        Иначе
            // выбор менеджера печати
            ИспользуемыйМенеджерПечати = ИмяДополнительногоМенеджераПечати;
            Если ПустаяСтрока(ИспользуемыйМенеджерПечати) Тогда
                ИспользуемыйМенеджерПечати = ИмяМенеджераПечати;
            КонецЕсли;
            МенеджерПечати = ОбщегоНазначения.МенеджерОбъектаПоПолномуИмени(ИспользуемыйМенеджерПечати);

            // печать внутренней печатной формы
            МенеджерПечати.Печать(МассивОбъектов, ПараметрыПечати, ВременнаяКоллекцияДляОднойПечатнойФормы, ОбъектыПечати, ПараметрыВывода);
        КонецЕсли;

        // обновление коллекции
        Отказ = ВременнаяКоллекцияДляОднойПечатнойФормы.Количество() = 0;
        // предполагается одна печатная форма, но для обратной совместимости принимается вся коллекция.
        Для Каждого ВременнаяПечатнаяФорма Из ВременнаяКоллекцияДляОднойПечатнойФормы Цикл
            Если ВременнаяПечатнаяФорма.ТабличныйДокумент <> Неопределено Тогда
                ПечатнаяФорма = КоллекцияПечатныхФорм.Добавить();
                ЗаполнитьЗначенияСвойств(ПечатнаяФорма, ВременнаяПечатнаяФорма);
                Если ВременнаяКоллекцияДляОднойПечатнойФормы.Количество() = 1 Тогда
                    ПечатнаяФорма.ИмяМакета = ИмяМакета;
                    ПечатнаяФорма.ИмяВРЕГ = ВРег(ИмяМакета);
                КонецЕсли;
            Иначе
                // возникла ошибка при формировании печатной формы
                Отказ = Истина;
            КонецЕсли;
        КонецЦикла;

        // вызов исключения при возникновении ошибки
        Если Отказ Тогда
            ТекстСообщенияОбОшибке = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
                НСтр("ru = 'При формировании печатной формы ""%1"" возникла ошибка. Обратитесь к администратору.'"), ИмяМакета);
            ВызватьИсключение(ТекстСообщенияОбОшибке);
        КонецЕсли;

    КонецЦикла;

    // установка количества экземпляров табличным документам
    Для Каждого ПечатнаяФорма Из КоллекцияПечатныхФорм Цикл
        Если ДобавленныеВнешниеПечатныеФормы.Найти(ПечатнаяФорма.ИмяМакета) <> Неопределено Тогда
            ПечатнаяФорма.Экземпляров = 0; // для автоматически добавленных форм
        КонецЕсли;
        Если ПечатнаяФорма.ТабличныйДокумент <> Неопределено Тогда
            ПечатнаяФорма.ТабличныйДокумент.КоличествоЭкземпляров = ПечатнаяФорма.Экземпляров;
        КонецЕсли;
    КонецЦикла;

КонецПроцедуры