Здравствуйте. Замерил производительность проведения документа и заметил, что документ проводится допустим 30 секунд, и самое большую часть времени его проведения занимает такая вещь (70% времени).
Функция ВыполнитьЗапросПоРасходам(Граница, Организация, ТаблицаФильтров, ТаблицаБлокировок = Неопределено) Экспорт
    
    УстановитьБлокировкиПоТаблицеФильтров("РасходыПриУСН", ТаблицаФильтров, ТаблицаБлокировок, Организация);
    ОбработатьТаблицуФильтров(ТаблицаФильтров);
    
    Запрос = Новый Запрос;
    Запрос.УстановитьПараметр("Организация", Организация);
    Запрос.УстановитьПараметр("Граница",     Граница);
    Для каждого Фильтр Из ТаблицаФильтров Цикл
        Запрос.УстановитьПараметр(Фильтр.ИмяПоля,     Фильтр.ЗначениеПоля);
    КонецЦикла;
    Текст =
    "ВЫБРАТЬ
    |    РасходыУСН.Организация,
    |    РасходыУСН.ВидРасхода,
    |    РасходыУСН.ЭлементРасхода,
    |    РасходыУСН.СчетУчета,
    |    РасходыУСН.Валюта,
    |    РасходыУСН.ДоговорКонтрагента,
    |    РасходыУСН.РасчетныйДокумент,
    |    РасходыУСН.СтатусыПартийУСН,
    |    РасходыУСН.Партия,
    |    РасходыУСН.ОтражениеВУСН,
    |    РасходыУСН.СтатусыОплатыРасходовУСН,
    |    РасходыУСН.СтатусыОплатыРасходовУСН.Порядок КАК СтатусыОплатыРасходовУСНПорядок,
    |    СУММА(РасходыУСН.КоличествоОстаток) КАК Количество,
    |    СУММА(РасходыУСН.СуммаОстаток) КАК Сумма,
    |    СУММА(РасходыУСН.НДСОстаток) КАК НДС,
    |    РасходыУСН.НомерСтрокиДокумента КАК НомерСтрокиДокумента,
    |    РасходыУСН.РеквизитыДокументаОплаты КАК РеквизитыДокументаОплаты,
    |    РасходыУСН.Партия.Дата КАК ПартияДата,
    |    РасходыУСН.РасчетныйДокумент.Дата КАК РасчетныйДокументДата
    |ИЗ
    |    РегистрНакопления.РасходыПриУСН.Остатки(&Граница, Организация = &Организация";
    
    Для каждого Фильтр Из ТаблицаФильтров Цикл
        Если Найти(Фильтр.Условие, "В") = 0 Тогда
            Текст = Текст + " И " + Фильтр.ИмяПоля + " " + Фильтр.Условие + " &" + Фильтр.ИмяПоля;
        Иначе
            Текст = Текст + " И " + Фильтр.ИмяПоля + " " + Фильтр.Условие + " (&" + Фильтр.ИмяПоля + ")";
        КонецЕсли;
    КонецЦикла;
    
    Текст = Текст + ") КАК РасходыУСН
    |
    |СГРУППИРОВАТЬ ПО
    |    РасходыУСН.Организация,
    |    РасходыУСН.ВидРасхода,
    |    РасходыУСН.ЭлементРасхода,
    |    РасходыУСН.СчетУчета,
    |    РасходыУСН.Валюта,
    |    РасходыУСН.ДоговорКонтрагента,
    |    РасходыУСН.РасчетныйДокумент,
    |    РасходыУСН.СтатусыПартийУСН,
    |    РасходыУСН.Партия,
    |    РасходыУСН.ОтражениеВУСН,
    |    РасходыУСН.СтатусыОплатыРасходовУСН,
    |    РасходыУСН.НомерСтрокиДокумента,
    |    РасходыУСН.РеквизитыДокументаОплаты
    |
    |ДЛЯ ИЗМЕНЕНИЯ
    |
    |УПОРЯДОЧИТЬ ПО
    |    СтатусыОплатыРасходовУСНПорядок,
    |    ПартияДата,
    |    РасчетныйДокументДата,
    |    НомерСтрокиДокумента";
    
    Запрос.Текст = Текст;
    Возврат Запрос.Выполнить().Выгрузить();

Как это дело ускорить, мб что-нить можно сделать с регистром накопления, там доп галки индексацию ему выставить ?  или взять остаточную таблицу?

(58) У вас в РасходыУСН.Партия и РасходыУСН.РасчетныйДокумент сильно много различных видов документов хранится или все одного вида?

(63) ну, все, которые вспомнишь, они все есть.

(62) Да.
Включить мозг и осилить (43).

(58) штук 25.
(65) а что я не так в нем сделал я же скинул результирующий, и сказал что ругается на выбрать второе, что я забыл.

(50) забыл ";" между запросами

(67) а они же разве не вместе? это же все один текст запроса или нет?

Для каждого Фильтр Из ТаблицаФильтров Цикл
        Если Найти(Фильтр.Условие, "В") = 0 Тогда
            Текст = Текст + " И " + Фильтр.ИмяПоля + " " + Фильтр.Условие + " &" + Фильтр.ИмяПоля;
        Иначе
            Текст = Текст + " И " + Фильтр.ИмяПоля + " " + Фильтр.Условие + " (&" + Фильтр.ИмяПоля + ")";
        КонецЕсли;
    КонецЦикла;
    

теперь это мешается, а они вообще нужны? хотя думаю да.

анализируя модуль из типовой БП 2.0 пришел к  выводу что код, идентичен за исключением состава измерений партий и тд, туда добавлены типовые раруса. сам замедление в выполнение запроса заключается в следующих строчках.
    |УПОРЯДОЧИТЬ ПО
    |    ПартияДата,
    |    РасчетныйДокументДата

убирая их скорость возрастает, как думаете, мб стоит сначала выгрузить запрос, а потом ТЗ.Сортировать("Партия.Дата,РАсчетныйДокумент.Дата"); ?

(68) Это вообще то пакетный запрос, каждый запрос в пакете разделяется ";"

(71) фильтры не подошли я ушел от этой идеи, появилась вот другая, нагрузку на железо кинуть.

а железо вроде должнго вытянуть эти сортировки.

а не ошибся, в субд и то быстрее было . вариант пока без    |    ПартияДата,
    |    РасчетныйДокументДата работает самый шустрый.
со временными таблицами фильтры не подсунул ...

(72) Чой то ?
Там надо было просто ГДЕ Остатки.Организациядобавить в текст запроса ну и в условия:

Для каждого Фильтр Из ТаблицаФильтров Цикл

        Если Найти(Фильтр.Условие, "В") = 0 Тогда
            Текст = Текст + " И Остатки." + Фильтр.ИмяПоля + " " + Фильтр.Условие + " &" + Фильтр.ИмяПоля;
        Иначе
            Текст = Текст + " И Остатки." + Фильтр.ИмяПоля + " " + Фильтр.Условие + " (&" + Фильтр.ИмяПоля + ")";
        КонецЕсли;
    КонецЦикла;

(74) ясен пень, нет соединения со всеми табличками доков из составного типа.
Если знаешь, какие именно должны участвовать в выборке, можешь явно ограничить выборку только из них.

Запрос написан, болие или менее нормально. Нужно провести реиндексацию базы в скуле или файле.

(66) "штук 25" - и все используются?

(76) не тока 5-6 документов вообще в конфигурации не используется ( не работают с ними пользователи).
(77) проводил, не сильно помогло.

(0) Чтобы понять, как ускорить запрос форум должен видеть:

1. Текст условия, которое формирует цикл в топике
2. Структуры данных левой части, на которые сие условие накладывается
3. Много ли данных возвращает запрос в конце

Если в левой части условия много точек - возможно замедление, если в левой части условия составной тип данных - тоже возможно замедление, если в правой части при условии "В" большой массив данных - также возможно замедление.

Если этой информации нет - состав преступления отсутствует.

Сразу могу сказать, что вот это РасходыУСН.Партия.Дата и это РасходыУСН.РасчетныйДокумент.Дата - соединение со всеми таблицами документов, коими может быть партия / платежка, со всеми вытекающими последствиями. Да и вот это РасходыУСН.Партия - тут, если нужно представление получить (скажем, при выводе документа в отчет/сообщение), известен идентификатор, а какой тип документа - не понятно системе, вот и опять идет запрос ко всем таблицам документов, коими может быть партия.

(80)
1.запрос выкладывал, могу текст уже конечный выложить.
2. Тоже могу выложить все фильтры
3. Данные могут плавать количество так точно не скажу.

(74) "со временными таблицами фильтры не подсунул ..."
Всё-таки победи временные таблицы.
А вот если не поможет (а это очень вероятно), то надо курить более сложные варианты.

(82) надо еще фильтры подсунуть, да пробывал я со временными, время чуть чуть меньше, но не так как без упорядночить по тем 2 датам.

(81) Если заранее известны типы партии и расчетного документа, то можно добиться ускорения посредством

ВЫРАЗИТЬ(Партия КАК Документ.ПоступлениеТоваровУслуг)

и в условиях виртуальной таблицы

Партия ССЫЛКА Документ.ПоступлениеТоваровУслуг

в этом случае система будет рассматривать только партии, которые сделаны ПТиУ - будет ускорение, но снижение универсальности.

К слову: если использовать ИЛИ в фильтре - система не будет использовать индексы - тоже может быть замедление. В этом случае лучше строить запросы через ОБЪЕДИНИТЬ ВСЕ, если, конечно, индексы есть, если нет - то смысл теряется.

индексы как их определить?
нет не тока поступление.

(83) Во сколько раз ускоряет запрос выключение упорядочивания?

Макс.ускорение можно получить так:

1) получить общий список документов Партия и РасчетныйДокумент из результат запроса без упорядочивания - их не должно быть слишком много. Кстати, сколько у тебя получается?

2) программно построить текст запроса-объединения такого вида

"ВЫБРАТЬ
Ссылка,
Дата
ПОМЕСТИТЬ ДокиДаты
Из
Документ.ВидДокумента1 КАК Док
ГДЕ Ссылка В (&МассивВсехДокументов)

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
Ссылка,
Дата
ПОМЕСТИТЬ ДокиДаты
Из
Документ.ВидДокумента2 КАК Док
ГДЕ Ссылка В (&МассивВсехДокументов)
...

ИНДЕКСИРОВАТЬ ПО
ССЫЛКА"

и т.д. по всем возможным видам документов (можно перебрать список видов из метаданных регистра).

Тут мы получим все даты.
И эту таблицу присоединить к первой (несортированной) и отсортировать.

Всё это делается одним пакетным запросом.

(83) см.(75)

(0)
1. Нужно изменить алгоритм получения даты у партии и расчетного документа.
2. в запросе не нужно использовать сгруппировать, так как 1с уже это делает за счет получения данных из вирт. таблицы остатков.

Для начала оставь все как есть, только убери:
- группировку,
- упорядочивание
- получение данных через точку (Партия.Дата, РасчетныйДокумент.Дата)

(89) "получение данных через точку " - так ему нужна сортировка по дате. А взять её можно только из таблиц документов.

(87) извините, но чувствую будет не очень. общий список документов это выбрать все документы?

(0) в качестве теста: поля фильтра расположить в том порядке, как они заданы в конфигураторе. тогда субд будет оптимально использовать индексы

(75) не понял вас и не увидел сообщения.

(92) располжены где ?

(92) точнее это же там партия и тд и тп.

(89) убрал упорядочивание и скорость ВЫРОСЛА в разы же в 3 раза. вот и спрашиваю чем это черевато.

сделал так
    |УПОРЯДОЧИТЬ ПО
    |    СтатусыОплатыРасходовУСНПорядок,
//    |    ПартияДата,
//    |    РасчетныйДокументДата,
    |    НомерСтрокиДокумента";

и скорость взлетела в 3 раза.

(96) нужно смотреть дальше по коду. это из какой конфигурации?

поэтому спрашиваю, что ждать, соотвественро еще убрал
//    |    ПартияДата,

//    |    РасчетныйДокументДата, из выбрать ибо лишние поля не нужны.

Общепит 2.0, она на основе БП 2.0 там такой же запрос, но нет общепитдокументов (общепит это рарус).

(97) группировки и получение данных через точку тоже убирал?

(100) проведение по партиям?

"ВЫБРАТЬ
    |    РасходыУСН.Организация,
    |    РасходыУСН.ВидРасхода,
    |    РасходыУСН.ЭлементРасхода,
    |    РасходыУСН.СчетУчета,
    |    РасходыУСН.Валюта,
    |    РасходыУСН.ДоговорКонтрагента,
    |    РасходыУСН.РасчетныйДокумент,
    |    РасходыУСН.СтатусыПартийУСН,
    |    РасходыУСН.Партия,
    |    РасходыУСН.ОтражениеВУСН,
    |    РасходыУСН.СтатусыОплатыРасходовУСН,
    |    РасходыУСН.СтатусыОплатыРасходовУСН.Порядок КАК СтатусыОплатыРасходовУСНПорядок,
    |    СУММА(РасходыУСН.КоличествоОстаток) КАК Количество,
    |    СУММА(РасходыУСН.СуммаОстаток) КАК Сумма,
    |    СУММА(РасходыУСН.НДСОстаток) КАК НДС,
    |    РасходыУСН.НомерСтрокиДокумента КАК НомерСтрокиДокумента,
    |    РасходыУСН.РеквизитыДокументаОплаты КАК РеквизитыДокументаОплаты
//    |    РасходыУСН.Партия.Дата КАК ПартияДата,
//    |    РасходыУСН.РасчетныйДокумент.Дата КАК РасчетныйДокументДата
    |ИЗ
    |    РегистрНакопления.РасходыПриУСН.Остатки(&Граница, Организация = &Организация";
    
    Для каждого Фильтр Из ТаблицаФильтров Цикл
        Если Найти(Фильтр.Условие, "В") = 0 Тогда
            Текст = Текст + " И " + Фильтр.ИмяПоля + " " + Фильтр.Условие + " &" + Фильтр.ИмяПоля;
        Иначе
            Текст = Текст + " И " + Фильтр.ИмяПоля + " " + Фильтр.Условие + " (&" + Фильтр.ИмяПоля + ")";
        КонецЕсли;
    КонецЦикла;
    
    Текст = Текст + ") КАК РасходыУСН
    |
    |СГРУППИРОВАТЬ ПО
    |    РасходыУСН.Организация,
    |    РасходыУСН.ВидРасхода,
    |    РасходыУСН.ЭлементРасхода,
    |    РасходыУСН.СчетУчета,
    |    РасходыУСН.Валюта,
    |    РасходыУСН.ДоговорКонтрагента,
    |    РасходыУСН.РасчетныйДокумент,
    |    РасходыУСН.СтатусыПартийУСН,
    |    РасходыУСН.Партия,
    |    РасходыУСН.ОтражениеВУСН,
    |    РасходыУСН.СтатусыОплатыРасходовУСН,
    |    РасходыУСН.НомерСтрокиДокумента,
    |    РасходыУСН.РеквизитыДокументаОплаты
    |
//    |ДЛЯ ИЗМЕНЕНИЯ
//    |
    |УПОРЯДОЧИТЬ ПО
    |    СтатусыОплатыРасходовУСНПорядок,
//    |    ПартияДата,
//    |    РасчетныйДокументДата,
    |    НомерСтрокиДокумента";

(102) да есть партионный учет. ФИФО.

щас такое дело и летает ...

(97) смотри, как бы не получилось то что тебе в (57) сказали :)))

14 минут на проведения целого дня, а было 40 минут, разница есть? документ оборот растет.

(91) Это будет:
ВЫБРАТЬ РАЗЛИЧНЫЕ
Партия
ПОМЕСТИТЬ ДокументыДляДаты  // и эту ВТ будем использовать для отбора документов
ИЗ Остатки
ОБЪЕДИНИТЬ
ВЫБРАТЬ РАЗЛИЧНЫЕ
РасчетныйДокумент
ИЗ Остатки

Чувствую, проще самому написать...

(106) поэтому ищу алтернативу, чтобы не получилось как в (57) я уже понял, примерно зачем нужно упорядочивание , но не понимаю почему даты могут выйти в разброс )

(108) вообще никогда не использовал ВТ и во франче где раньше работал, открещивались, когда спрашивал про это.

(104) посмотри в конфигураторе сколько типов документов в измерении партий и сколько типов в расчетных документах

а типовой запрос, с не знаниями ВТ еще под ВТ крутить ну скажем не надежно )

(104) 21, 21 где то так.

(110) теперь все по-взрослому.

пробывать ВТ будут сам отдельно, но не в типовой и в рабочей конфигурации, с этим думаю на 3 месяца затянется, а решение надо щас прикинуть, правда попа моя от этого не горит, но емае обидно, если не поправлю. вроде нашел решение, но может выйти xFO. вот еще жду вариантов.

А еще можно в регистр добавить измерения "ПартияДата" и "РасчетныйДокументДата" и записывать их при проведении. Тогда у тебя сразу будут нужные даты и не будет разименовывания. Но тут вопрос - насколько далеко ты готов зайти ради оптимизации :))

(103) Ты тупо удалил разименовывание через точку. Это оно тормозило, а не упорядочивание.

(115) решение такое:
получение данных из регистра и поместить во временную таблицу, вторым запросом через объединение сделать получение дат из таблиц документов шаблон:

ВЫБРАТЬ Док.Ссылка, Док.Дата ИЗ Документ.ИмяДокумента ГДЕ Док.Ссылка В (ВЫБРАТЬ РН.Партия ИЗ ДанныеИзРегистра КАК РН ГДЕ РН.Партия Ссылка Документ.ИмяДокумента) Или  Док.Ссылка В (ВЫБРАТЬ РН.РАсчетный Документ ИЗ ДанныеИзРегистра КАК РН ГДЕ РН.РАсчетный Документ Ссылка Документ.ИмяДокумента)
ОБЪЕДИНИТЬ ВСЕ ... и тд в конце установить ИНДЕКСИРОВАТЬ ПО Ссылка
и так по все типам документов и потом в третьем запросе сделать левое соединение

вроде уже такой вариант проскакивал. работы там на час. После этого все должно встать на свои места.

(103) в типовой бух там 44 типа документов в партии и 40 в расчетном документе, при получении данных через точку получается что в основному запросу (в котором 3 таблицы) присоединяются еще 84 таблицы. От такого запроса можно оживать все что угодно.

Проверил, работает (только фильтры чуть по-другому написал, их не проверял :) )

    Запрос = Новый Запрос;
    
    Запрос.УстановитьПараметр("Организация", Организация);
    Запрос.УстановитьПараметр("Граница",     Граница);
    Для каждого Фильтр Из ТаблицаФильтров Цикл
        Запрос.УстановитьПараметр(Фильтр.ИмяПоля,  Фильтр.ЗначениеПоля);
    КонецЦикла;
    
    ТекстФильтра = "";
    Для каждого Фильтр Из ТаблицаФильтров Цикл
        Если Найти(Фильтр.Условие, "В") = 0 Тогда
            ТекстФильтра = ТекстФильтра + " И " + Фильтр.ИмяПоля + " " + Фильтр.Условие + " &" + Фильтр.ИмяПоля;
        Иначе
            ТекстФильтра = ТекстФильтра + " И " + Фильтр.ИмяПоля + " " + Фильтр.Условие + " (&" + Фильтр.ИмяПоля + ")";
        КонецЕсли;
    КонецЦикла;
    
    Текст =
    "ВЫБРАТЬ
    |    РасходыУСН.Организация,
    |    РасходыУСН.ВидРасхода,
    |    РасходыУСН.ЭлементРасхода,
    |    РасходыУСН.СчетУчета,
    |    РасходыУСН.Валюта,
    |    РасходыУСН.ДоговорКонтрагента,
    |    РасходыУСН.РасчетныйДокумент,
    |    РасходыУСН.СтатусыПартийУСН,
    |    РасходыУСН.Партия,
    |    РасходыУСН.ОтражениеВУСН,
    |    РасходыУСН.СтатусыОплатыРасходовУСН,
    |    РасходыУСН.СтатусыОплатыРасходовУСН.Порядок КАК СтатусыОплатыРасходовУСНПорядок,
    |    СУММА(РасходыУСН.КоличествоОстаток) КАК Количество,
    |    СУММА(РасходыУСН.СуммаОстаток) КАК Сумма,
    |    СУММА(РасходыУСН.НДСОстаток) КАК НДС,
    |    РасходыУСН.НомерСтрокиДокумента КАК НомерСтрокиДокумента,
    |    РасходыУСН.РеквизитыДокументаОплаты КАК РеквизитыДокументаОплаты
    |ПОМЕСТИТЬ Остатки
    |ИЗ
    |    РегистрНакопления.РасходыПриУСН.Остатки(
    |            &Граница,
    |            Организация = &Организация
    |                И &ТекстФильтра) КАК РасходыУСН
    |
    |СГРУППИРОВАТЬ ПО
    |    РасходыУСН.Организация,
    |    РасходыУСН.ВидРасхода,
    |    РасходыУСН.ЭлементРасхода,
    |    РасходыУСН.СчетУчета,
    |    РасходыУСН.Валюта,
    |    РасходыУСН.ДоговорКонтрагента,
    |    РасходыУСН.РасчетныйДокумент,
    |    РасходыУСН.СтатусыПартийУСН,
    |    РасходыУСН.Партия,
    |    РасходыУСН.ОтражениеВУСН,
    |    РасходыУСН.СтатусыОплатыРасходовУСН,
    |    РасходыУСН.НомерСтрокиДокумента,
    |    РасходыУСН.РеквизитыДокументаОплаты,
    |    РасходыУСН.СтатусыОплатыРасходовУСН.Порядок
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ РАЗЛИЧНЫЕ
    |    Остатки.Партия КАК Ссылка
    |ПОМЕСТИТЬ ДокументыВсе
    |ИЗ
    |    Остатки КАК Остатки
    |
    |ОБЪЕДИНИТЬ
    |
    |ВЫБРАТЬ РАЗЛИЧНЫЕ
    |    Остатки.РасчетныйДокумент
    |ИЗ
    |    Остатки КАК Остатки
    |";
    
    Текст = СтрЗаменить(Текст, "И &ТекстФильтра", ТекстФильтра);
    
    МассивИмен = Новый Массив;
    Для каждого Тип Из Метаданные.РегистрыНакопления.РасходыПриУСН.Измерения.Партия.Тип.Типы() Цикл
        ИмяМД = Метаданные.НайтиПоТипу(Тип).Имя;
        Если МассивИмен.Найти(ИмяМД) = Неопределено Тогда
            МассивИмен.Добавить(ИмяМД);
        КонецЕсли;
    КонецЦикла;
    
    ТекстДаты = "";
    Для каждого ИмяМД Из МассивИмен Цикл
    
        ТекстДаты = ТекстДаты
            + ?(ТекстДаты = "", "", Символы.ПС + "ОБЪЕДИНИТЬ ВСЕ")
            + Символы.ПС + "ВЫБРАТЬ Ссылка, Дата "
            + ?(ТекстДаты = "", "ПОМЕСТИТЬ ДокиДаты", "")
            + Символы.ПС + " ИЗ Документ." + ИмяМД + " КАК Док ГДЕ Ссылка В (ВЫБРАТЬ Ссылка ИЗ ДокументыВсе)"
    
    КонецЦикла;
        
    Текст = Текст
    + ";" + ТекстДаты
    + "
    |;
    |    ВЫБРАТЬ
    |    Остатки.Организация,
    |    Остатки.ВидРасхода,
    |    Остатки.ЭлементРасхода,
    |    Остатки.СчетУчета,
    |    Остатки.Валюта,
    |    Остатки.ДоговорКонтрагента,
    |    Остатки.РасчетныйДокумент,
    |    ДатыРасчетныхДокументов.Дата КАК РасчетныйДокументДата,
    |    Остатки.СтатусыПартийУСН,
    |    Остатки.Партия,
    |    ДатыПартий.Дата КАК ПартияДата,
    |    Остатки.ОтражениеВУСН,
    |    Остатки.СтатусыОплатыРасходовУСН,
    |    Остатки.СтатусыОплатыРасходовУСНПорядок,
    |    Остатки.Количество,
    |    Остатки.Сумма,
    |    Остатки.НДС,
    |    Остатки.НомерСтрокиДокумента,
    |    Остатки.РеквизитыДокументаОплаты
    |ИЗ
    |    Остатки КАК Остатки
    |ЛЕВОЕ СОЕДИНЕНИЕ ДокиДаты КАК ДатыПартий
    |    ПО Остатки.Партия = ДатыПартий.Ссылка
    |ЛЕВОЕ СОЕДИНЕНИЕ ДокиДаты КАК ДатыРасчетныхДокументов
    |    ПО Остатки.РасчетныйДокумент = ДатыРасчетныхДокументов.Ссылка
    |УПОРЯДОЧИТЬ ПО
    |    СтатусыОплатыРасходовУСНПорядок,
    |    ПартияДата,
    |    РасчетныйДокументДата,
    |    НомерСтрокиДокумента
    |";

Херракс!

Функция ПолучитьТаблицуОстатков() Экспорт
    Запрос=Новый Запрос;
    МенеджерВТ=Новый МенеджерВременныхТаблиц;
    Запрос.МенеджерВременныхТаблиц=МенеджерВТ;
    Запрос.Текст=
    "ВЫБРАТЬ
    |    РасходыУСН.Организация,
    |    РасходыУСН.ВидРасхода,
    |    РасходыУСН.ЭлементРасхода,
    |    РасходыУСН.СчетУчета,
    |    РасходыУСН.Валюта,
    |    РасходыУСН.ДоговорКонтрагента,
    |    РасходыУСН.РасчетныйДокумент,
    |    РасходыУСН.СтатусыПартийУСН,
    |    РасходыУСН.Партия,
    |    РасходыУСН.ОтражениеВУСН,
    |    РасходыУСН.СтатусыОплатыРасходовУСН,
    |    РасходыУСН.КоличествоОстаток КАК Количество,
    |    РасходыУСН.СуммаОстаток КАК Сумма,
    |    РасходыУСН.НДСОстаток КАК НДС,
    |    РасходыУСН.НомерСтрокиДокумента КАК НомерСтрокиДокумента,
    |    РасходыУСН.РеквизитыДокументаОплаты КАК РеквизитыДокументаОплаты
    |ПОМЕСТИТЬ Остатки
    |ИЗ
    |    РегистрНакопления.РасходыПриУСН.Остатки() КАК РасходыУСН
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ РАЗЛИЧНЫЕ
    |    Остатки.РасчетныйДокумент КАК Документ,
    |    0 КАК НомерТипа
    |ИЗ
    |    Остатки КАК Остатки
    |
    |ОБЪЕДИНИТЬ ВСЕ
    |
    |ВЫБРАТЬ РАЗЛИЧНЫЕ
    |    Остатки.Партия,
    |    0
    |ИЗ
    |    Остатки КАК Остатки";
    
    
    ТаблицаДокументов=Запрос.Выполнить().Выгрузить();
    СоответствиеНомераТипаИИмени=Новый Соответствие;
    ПоследнийНомерТипа=0;
    НомерТипа=0;
    Для Каждого СтрокаТЗ ИЗ ТаблицаДокументов Цикл
        Если Не ЗначениеЗаполнено(СтрокаТЗ.Документ) Тогда
            Продолжить;
        КонецЕсли;
        ИмяДокумента=СтрЗаменить(xmltypeof(СтрокаТЗ.Документ).ИмяТипа,"DocumentRef.","");
        СтрокаСоответствия=СоответствиеНомераТипаИИмени.Получить(ИмяДокумента);
        Если СтрокаСоответствия=Неопределено Тогда
            НомерТипа=ПоследнийНомерТипа+1;
            СоответствиеНомераТипаИИмени.Вставить(ИмяДокумента,НомерТипа);
            ПоследнийНомерТипа=НомерТипа;
        Иначе
            НомерТипа=СтрокаСоответствия.Значение;
        КонецЕсли;
        СтрокаТЗ.НомерТипа=НомерТипа;
    КонецЦикла;
    
    Запрос.Текст=
    "ВЫБРАТЬ
    |    ТаблицаДокументов.Документ,
    |    ТаблицаДокументов.НомерТипа КАК НомерТипа
    |ПОМЕСТИТЬ ТаблицаДокументов
    |ИЗ
    |    &ТаблицаДокументов КАК ТаблицаДокументов
    |
    |ИНДЕКСИРОВАТЬ ПО
    |    НомерТипа
    |;";
    Запрос.УстановитьПараметр("ТаблицаДокументов",ТаблицаДокументов);
    Префикс="";
    Суффикс="ПОМЕСТИТЬ ДатыДокументов";
    Для Каждого СтрокаСоответствия Из СоответствиеНомераТипаИИмени Цикл
        Запрос.УстановитьПараметр("НомерТипа"+Формат(СтрокаСоответствия.Значение,"ЧГ="),СтрокаСоответствия.Значение);
        ТекущееИмяДокумента=СтрокаСоответствия.Ключ;
        Запрос.Текст=Запрос.Текст+Префикс+"
        |ВЫБРАТЬ
        |    ТаблицаДанных.Ссылка,
        |    ТаблицаДанных.Дата
        |"+Суффикс+"
        |ИЗ
        |    Документ."+ТекущееИмяДокумента+" КАК ТаблицаДанных
        |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ ТаблицаДокументов КАК ТаблицаДокументов
        |        ПО ТаблицаДанных.Ссылка = ТаблицаДокументов.Документ
        |            И (ТаблицаДокументов.НомерТипа = &НомерТипа"+Формат(СтрокаСоответствия.Значение,"ЧГ=")+")
        |";
        Суффикс="";
        Префикс="ОБЪЕДИНИТЬ ВСЕ";
    КонецЦикла;
    Запрос.Текст=Запрос.Текст+"
    |ИНДЕКСИРОВАТЬ ПО
    |ТаблицаДанных.Ссылка;";
    
    Запрос.Текст=Запрос.Текст+
    "
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |    Остатки.Организация,
    |    Остатки.ВидРасхода,
    |    Остатки.ЭлементРасхода,
    |    Остатки.СчетУчета,
    |    Остатки.Валюта,
    |    Остатки.ДоговорКонтрагента,
    |    Остатки.РасчетныйДокумент,
    |    Остатки.СтатусыПартийУСН,
    |    Остатки.Партия,
    |    Остатки.ОтражениеВУСН,
    |    Остатки.СтатусыОплатыРасходовУСН,
    |    Остатки.СтатусыОплатыРасходовУСН.Порядок КАК СтатусыОплатыРасходовУСНПорядок,
    |    Остатки.Количество,
    |    Остатки.Сумма,
    |    Остатки.НДС,
    |    Остатки.НомерСтрокиДокумента КАК НомерСтрокиДокумента,
    |    Остатки.РеквизитыДокументаОплаты,
    |    ЕСТЬNULL(ДатыДокументовПартии.Дата, ДАТАВРЕМЯ(1, 1, 1)) КАК ПартияДата,
    |    ЕСТЬNULL(ДатыДокументовРасчетныхДокументов.Дата, ДАТАВРЕМЯ(1, 1, 1)) КАК РасчетныйДокументДата
    |ИЗ
    |    Остатки КАК Остатки
    |        ЛЕВОЕ СОЕДИНЕНИЕ ДатыДокументов КАК ДатыДокументовПартии
    |        ПО Остатки.Партия = ДатыДокументовПартии.Ссылка
    |        ЛЕВОЕ СОЕДИНЕНИЕ ДатыДокументов КАК ДатыДокументовРасчетныхДокументов
    |        ПО Остатки.РасчетныйДокумент = ДатыДокументовРасчетныхДокументов.Ссылка
    |
    |УПОРЯДОЧИТЬ ПО
    |    СтатусыОплатыРасходовУСНПорядок,
    |    ПартияДата,
    |    РасчетныйДокументДата,
    |    НомерСтрокиДокумента";
    
    ТЗ=Запрос.Выполнить().Выгрузить();
КонецФункции

1) Фильтры на ВТ сами крутите.
2) Не уверен в связке

ВНУТРЕННЕЕ СОЕДИНЕНИЕ ТаблицаДокументов КАК ТаблицаДокументов
        |        ПО ТаблицаДанных.Ссылка = ТаблицаДокументов.Документ
        |            И (ТаблицаДокументов.НомерТипа =&НомерТипа

Будет ли тут задействованы индексы (2 простых, 1-ый - индекс на ссылку в таблицы шапки документа, 2-ой - индекс временной таблицы).

3) Лучше выполнять на сервере

4) Респект ptiz за идею!

и кто же лучше сделал. спасибо большое буду прробывать оба варианта. результат потом расскажу.

Небольшая поправка...
после цикла
    Для каждого Тип Из Метаданные.РегистрыНакопления.РасходыПриУСН.Измерения.Партия.Тип.Типы() Цикл
...
КонецЦикла

надо еще на всякий пожарный цикл по типам РасчетныйДокумент:
    Для каждого Тип Из Метаданные.РегистрыНакопления.РасходыПриУСН.Измерения.РасчетныйДокумент.Тип.Типы() Цикл
        ИмяМД = Метаданные.НайтиПоТипу(Тип).Имя;
        Если МассивИмен.Найти(ИмяМД) = Неопределено Тогда
            МассивИмен.Добавить(ИмяМД);
        КонецЕсли;
    КонецЦикла;


Хотя оптимальнее по методу  H A D G E H O G s обойти таблицу и добавить только задействованные типы в МассивИмен.

(125) Это если на сервере, оптимальнее. А так - не уверен.

пробывал ваши оба варианта, ну скажем быстрее, но не так как с  первым вариантом где идет упорядочивание ...

мб вариант (126) сделал не совсем правильно.

(127) Зато алгоритм правильный.
А в числовых показателях что?

(129) а что в них? они по ОСВ не идут эти числа, по ОСВ вроде все в 0 закрывается, кроме 20 бываеют там по 0.01 копейки висят.

еще момент, есть общий модуль общепитовский, теперь он утягивает все это дело в следующей строчке
РегистрОстатков = РегистрыБухгалтерии.Хозрасчетный;
            СтрокаОстатков.Количество = РегистрОстатков.Остатки(МоментВремени,,СтруктураОтбора,"","Количество")[0].КоличествоОстатокДт;
            Если СтрокаОстатков.Количество < 0 Тогда
                СтрокаОстатков.Количество = 0;
            КонецЕсли;

все это в цикле
Для Каждого СтрокаПроизводства Из ТаблицаПроизводства Цикл
КонецЦикла;

как думаете из таблицыпроизводство взять номенклатуру все в запрос получить ТЗ и потом делать НайтиСтроки(), чем каждый раз искать

(131) Правильно мыслишь.

Жесть, жесть, жесть.

(133) что я так сильно туплю?

(134) Нет, это разработчики это чуда тупили.

Мы напишем собственную Библию. Меньше Содомы, больше Гоморры.

ну у них свое было мнение. у вас свое.
РегистрОстатков.Остатки(МоментВремени,,СтруктураОтбора,"","Количество")[0].КоличествоОстатокДт; так быстрее работает или можно
Запрос.Текст = "ТутаВозьмуОстаточную таблицу."

(127) Жаль у меня базы данных нет с большим этим регистром, чтобы проверить. На самом деле, большого ускорения и не должно было получиться, тут, скорее, спортивный интерес.

(137) запросом однозначно.

(138) Да ладно. Если остатки закрываются - должно помочь.

ну ваши варианты быстрее первоначального намного. причина очевидна этих выпуском, которые в партиях участвуют их в день по 200 штук где-то.
большое ускорение я вижу тока, когда упорядночить убираю эти 2 параметра и все.
(138) меня интересует быстрая скорость ибо закрытие месяца(восстановление последовательности) на недели затягивается.

(140) оставил варианта ptiz, т.к. в вашем чую я косякнул, ошибки не валит, но не верю я своим рукам )

+ к (139)
ВЫБРАТЬ ХозрасчетныйОстатки.КоличествоОстатокДт из РегистрБухгалтерии.Хозрасчетный.Остатки(&дата,Счет=&Счет,&видысубконто,Организация=&Организация  и Субконто1=&Номенклатура и Субконто2=&склад) КАК ХозрасчетныйОстатки

(143) тока Субконто1 В(&СписокНоменклатура)

тока один момент вместе даты, там моментвремени, а в момнете дата и документ, это как отразить.

единственный момент в таблице производства номеклатура может троится и тд. а они видать каждый раз лазиют для контроля количества, если <0 может быть, то дальше в мниус не идти.

РегистрОстатков.Остатки(МоментВремени,,СтруктураОтбора,"","Количество")[0].КоличествоОстатокДт;
будет медленее работать , чем
ВЫБРАТЬ ХозрасчетныйОстатки.КоличествоОстатокДт из РегистрБухгалтерии.Хозрасчетный.Остатки(&дата,Счет=&Счет,&видысубконто,Организация=&Организация  и Субконто1=&Номенклатура и Субконто2=&склад) КАК ХозрасчетныйОстатки ?

(144) смотря в каком месте смотреть.
СтруктураПараметров.МоментВремени

ну вот РегистрОстатков.Остатки(МоментВремени,,СтруктураОтбора,"","Количество")[0].КоличествоОстатокДт;  щас стало утягивать время, думаю как быть теперь

(146) еще как и чем больше объемы...

(148) запрос пишешь

там по 1000 строчек, и 1000 раз такая операция выполняется.
запрос. как ваш запрос все нормально, тока видысубконто как вы сделали я не понял, это в субконто да?
вместо даты, моментвремени пойдет?

(151) Почитай книжки.

(150) можешь сначала подготовить тз и подсунуть в параметры. для ингридентов по моему  там еще есть замены, аналоги.смотри внимательно.
видысубконто=Новый СписокЗначений;
видысубконто.Добавить(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.Номенклатура);
видысубконто.Добавить(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.склад);

Перед циклом вынес     
Запрос = Новый Запрос;
    МоиВидыСубконто = Новый СписокЗначений;
    МоиВидыСубконто.Добавить( ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.Номенклатура);
    МоиВидыСубконто.Добавить( ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.Склады);            
в цикле вместо РегистрОстатков.Остатки(МоментВремени,,СтруктураОтбора,"","Количество")[0].КоличествоОстатокДт;
Запрос.Текст = "ВЫБРАТЬ ХозрасчетныйОстатки.КоличествоОстатокДт из РегистрБухгалтерии.Хозрасчетный.Остатки(&МоментВремени,Счет=&Счет,&видысубконто,Организация=&Организация  и Субконто1=&Номенклатура и Субконто2=&склад) КАК ХозрасчетныйОстатки"
            Запрос.УстановитьПараметр("МоментВремени",МоментВремени);
            Запрос.УстановитьПараметр("Счет",СтруктураОтбора.Счет);
            Запрос.УстановитьПараметр("Организация",СтруктураОтбора.Организация);
            Запрос.УстановитьПараметр("Субконто1",СтруктураОтбора.Субконто1);
            Запрос.УстановитьПараметр("Субконто2",СтруктураОтбора.Субконто2);
            Запрос.УстановитьПараметр("видысубконто",МоиВидыСубконто);
            Выборка = Запрос.Выполнить().Выбрать();
            Если Выборка.Следующий() Тогда
                 СтрокаОстатков.Количество = Выборка.КоличествоОстатокДт;
             Иначе
                СтрокаОстатков.Количество = 0;
            КОнецЕсли;

тока параметры вметсе номенклатуры субконто1.

ХозрасчетныйОстатки.КоличествоОстатокДт оберни естьnull тогда
проверять в обходе не нужно будет. так все лучше чем рарус наваял

а ЕстьNULL(ХозрасчетныйОстатки.КоличествоОстатокДт,0) Тогда можно сразу Выборка[0].КоличествоОстатокДт делать да?

(157)  угу

ну пасибо прям то ли мне повезло то ли глючит один и тот же документ, на этом модуле, в 7 раз быстрее проходит все это.

с 14сек до 2 секунд сократилось.

хм еще бы их закрытый модуль по ключу защиты оптимизировать, вообще круто было бы.

ускорение работы процедуры Таблица.Свернуть()
    СтрокиАвтопеределов = ТаблицаПроизводства.НайтиСтроки(Новый Структура("ИзАвтопеределов", Истина));
    ТаблицаАвтопеределов = ТаблицаПроизводства.Скопировать(СтрокиАвтопеределов, "НоменклатурнаяГруппа, Ингредиент, РецептураАвтопередела, ИзАвтопеределов, КоличествоИнгредиентаНорма, КоэффициентИнгредиента, ЕдиницаИзмеренияИнгредиента");
    ТаблицаАвтопеределов.Свернуть("НоменклатурнаяГруппа, Ингредиент, РецептураАвтопередела, ИзАвтопеределов, КоэффициентИнгредиента, ЕдиницаИзмеренияИнгредиента", "КоличествоИнгредиентаНорма");

можно через запрос такое сделать?