Коллеги, есть несложный запрос:

ВЫБРАТЬ
   Себестоимость.Номенклатура                                КАК Номенклатура,
   Продажи.СтоимостьОборот                                  КАК Оборот,
   Себестоимость.СтоимостьОборот - Продажи.СтоимостьОборот КАК Прибыль
ИЗ
   РегистрНакопления.ПродажиСебестоимость.Обороты(&ДатаНач, &ДатаКон, ) КАК Себестоимость
   ПОЛНОЕ ВНЕШНЕЕ СОЕДИНЕНИЕ
   РегистрНакопления.Продажи.Обороты(&ДатаНач, &ДатаКон) КАК Продажи
   ПО Себестоимость.Номенклатура = Продажи.Номенклатура
УПОРЯДОЧИТЬ
   ПО Продажи.СтоимостьОборот УБЫВ

Мне нужно в порядке убывания оборота выбрать номеклатуры, сумма которых не больше 1000000. Подскажите возможно такое сделать с помощью запроса и как? Спасибо.

Где ТвояСумма <= 1000000

что не получается то?

(1) Не ну так бы я смог:) Мне по сути нужно ограничить выборку запроса: Выбрать первые номенклатуры, общая сумма оборотов которых не больше 1 млн

ну дак так и будет, если (1) вставиш... или я чото не понимаю?

(3) для ограничить есть слово ГДЕ. что не устраивает?

Ему поди нужно набрать на нужную сумму

(4) Обороты номенклатур упорядочены по убыванию:

номенклатура1 - 600 000
номенклатура2 - 400 000
номенклатура3 - 100 000

номенклатра3 не попадёт в выборку ибо на ней превышается этот млн

Мне в запросе нуждно получить первые номенклатуры сумма оборотов которых не больше 1 млн

хм, да. в запросе имхо так не сделать

(8) вот и я только на чудо надеюсь)

Можно сделать

(10) Выручайте)

присоединяюсь. просветите грешных

соединить само с собой с условием неравенства на накапливаемую сумму

(13) пример есть?

рыба:

ВЫБРАТЬ
   Т1.Номенклатура КАК Номенклатура,
   Т1.СтоимостьОборот КАК СтоимостьОборот
   СУММА(Т2.СтоимостьОборот) КАК СтоимостьОборотНакопительная
ИЗ Т КАК Т1
ЛЕВОЕ СОЕДИНЕНИЕ Т КАК Т2
ПО (Т1.СтоимостьОборот<=Т2.СтоимостьОборот) // будут проблемы с одинаковыми показателями
СГРУППИРОВАТЬ ПО
   Т1.Номенклатура,
   Т1.СтоимостьОборот
ИМЕЮЩИЕ
   СУММА(Т2.СтоимостьОборот)<СтоТыщМиллионов

(15) Идея понятна. Буду пробовать..

ВЫБРАТЬ
   Продажи.СтоимостьОборот КАК Оборот,
   Продажи.СтоимостьОборот - Себестоимость.СтоимостьОборот КАК Прибыль,
   Продажи.Номенклатура
ПОМЕСТИТЬ Таб
ИЗ
   РегистрНакопления.Продажи.Обороты(&ДатаНач, &ДатаКон, , ) КАК Продажи
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ПродажиСебестоимость.Обороты(&ДатаНач, &ДатаКон, , ) КАК Себестоимость
       ПО (Себестоимость.Номенклатура = Продажи.Номенклатура)
ГДЕ
   Продажи.СтоимостьОборот < &ОборотОграничение
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ВложенныйЗапрос.Номенклатура,
   ВложенныйЗапрос.Оборот КАК Оборот,
   ВложенныйЗапрос.Прибыль,
   ВложенныйЗапрос.ОборотНакопление
ИЗ
   (ВЫБРАТЬ
       Таб.Номенклатура КАК Номенклатура,
       Таб.Оборот КАК Оборот,
       Таб.Прибыль КАК Прибыль,
       СУММА(ЕСТЬNULL(Таб1.Оборот, 0)) КАК ОборотНакопление,
       МИНИМУМ(ЕСТЬNULL(Таб1.Оборот, 0)) КАК МаксОборот
   ИЗ
       Таб КАК Таб
           ЛЕВОЕ СОЕДИНЕНИЕ Таб КАК Таб1
           ПО (ВЫБОР
                   КОГДА Таб.Оборот = Таб1.Оборот
                       ТОГДА Таб.Номенклатура < Таб1.Номенклатура
                   ИНАЧЕ Таб.Оборот < Таб1.Оборот
               КОНЕЦ)
   
   СГРУППИРОВАТЬ ПО
       Таб.Номенклатура,
       Таб.Оборот,
       Таб.Прибыль
   
   ИМЕЮЩИЕ
       СУММА(ЕСТЬNULL(Таб1.Оборот, 0)) < &ОборотОграничение - МИНИМУМ(ЕСТЬNULL(Таб1.Оборот, 0))) КАК ВложенныйЗапрос

УПОРЯДОЧИТЬ ПО
   Оборот УБЫВ

Причесано
ВЫБРАТЬ
   Продажи.СтоимостьОборот КАК Оборот,
   Продажи.СтоимостьОборот - Себестоимость.СтоимостьОборот КАК Прибыль,
   Продажи.Номенклатура
ПОМЕСТИТЬ Таб
ИЗ
   РегистрНакопления.Продажи.Обороты(&ДатаНач, &ДатаКон, , ) КАК Продажи
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ПродажиСебестоимость.Обороты(&ДатаНач, &ДатаКон, , ) КАК Себестоимость
       ПО (Себестоимость.Номенклатура = Продажи.Номенклатура)
ГДЕ
   Продажи.СтоимостьОборот < &ОборотОграничение
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   Таб.Номенклатура КАК Номенклатура,
   Таб.Оборот КАК Оборот,
   Таб.Прибыль КАК Прибыль,
   СУММА(ЕСТЬNULL(Таб1.Оборот, 0)) КАК ОборотНакопление
ИЗ
   Таб КАК Таб
       ЛЕВОЕ СОЕДИНЕНИЕ Таб КАК Таб1
       ПО (ВЫБОР
               КОГДА Таб.Оборот = Таб1.Оборот
                   ТОГДА Таб.Номенклатура < Таб1.Номенклатура
               ИНАЧЕ Таб.Оборот < Таб1.Оборот
           КОНЕЦ)

СГРУППИРОВАТЬ ПО
   Таб.Номенклатура,
   Таб.Оборот,
   Таб.Прибыль

ИМЕЮЩИЕ
   СУММА(ЕСТЬNULL(Таб1.Оборот, 0)) < &ОборотОграничение - МИНИМУМ(ЕСТЬNULL(Таб1.Оборот, 0))

УПОРЯДОЧИТЬ ПО
   Оборот УБЫВ

(18) Додумались же до такого) Спасибо!

(19) Только условие в (18) немного поправить надо. Вот так:
ИМЕЮЩИЕ
   СУММА(ЕСТЬNULL(Таб1.Оборот, 0)) + Таб.Оборот < &ОборотОграничение

Чтобы однозначно упорядочить записи для совпадающих оборотов сравниваются ссылки. А так как накопительная сумма не учитытывает значение оборота текущей записи, то к  накопленной сумме СУММА(ЕСТЬNULL(Таб1.Оборот, 0)) нужно прибавить текущее значение Таб.Оборот

(20) Да, я заметил. Спасибо вам большое!